// Exploring Mandelbrot (my first applet)
// by Marcello Falco
// falco.phd@tiscali.it
//
// realized using the awesome Processing Programming Environment (thank you guys)
// http://processing.org


color col,init;
int iter=32;
int xint,yint;
double delta;
double xx1 = -2.0;
double yy1 = 1.25;
double xx2= 0.5;
double yy2= -1.25;
double xi,yi,xxi,yyi,xxf,yyf;
boolean flag = true;
boolean end = true;
BImage cp;


void setup() {
  size(256,256);  
  background(0,0,0);   
}


void loop() {
  init=color(255,255,255);

  if (flag && end) {
    if (xx1<xx2) {
      xxi=xx1;
      xxf=xx2;
    }
    else {
      xxi=xx2;
      xxf=xx1;
    }
    if (yy1<yy2) {
      yyi=yy1;
      yyf=yy2;
    }
    else {
      yyi=yy2;
      yyf=yy1;
    }
    xx1=xxi;
    xx2=xxf;
    yy1=yyi;
    yy2=yyf;
    delta=max(float(xx2-xx1),float(yy1-yy2));
    xxi=xx1-(delta-(xx2-xx1))/2.0;
    xxf=xxi+delta;
    yyi=yy1+(delta-(yy1-yy2))/2.0;
    yyf=yyi-delta;
    xx1=xxi;
    yy1=yyi;
    xx2=xxf;
    yy2=yyf;
    quadrante(0,0,256,256,init,init,init,init);
    cp = copy();
    end =false;
  }
  else {
    image(cp,0,0,256,256);
  }
  
  if ( flag && mousePressed ) {
    xint=mouseX;
    yint=mouseY;
    xi=delta*xint/256.0+xx1;
    yi=yy1-delta*yint/256.0;
    flag=false;
  }
  
  if (!flag) {
    stroke(255);
    noFill();
    rectMode(CORNERS);
    rect(xint,yint,mouseX,mouseY);
  }
}


void mouseReleased() {
  if (!flag) {
    xx2=delta*mouseX/256.0+xx1;
    yy2=yy1-delta*mouseY/256.0;
    xx1=xi;
    yy1=yi;
    flag=true;
    end=true;
  }
}


void keyPressed() {
    if (key == 'q' || key == 'Q') {
      xx1 = -2.0;
      yy1 = 1.25;
      xx2= 0.5;
      yy2= -1.25;
      delta=2.5;
      iter=32;      
      end=true;
    }
}


void keyReleased() {
  if ((key != 'q') && (key != 'Q')) {
    iter=iter*2;
    end=true;
  }
}
  

void quadrante (int x1, int y1, int x2, int y2, color c1, color c2, color c3, color c4) {

  int xm,ym;
  color c5,c6,c7,c8,c9;
  color neutro = color(255,255,255);
  
  xm=int(x1+(x2-x1)/2.0);
  ym=int(y1+(y2-y1)/2.0);
  
  if (c1 == neutro) {
    fuga(x1,y1);
    c1=col;
  }

  if (c2 == neutro) {
    fuga(x2,y1);
    c2=col;
  }
  
  if (c3 == neutro) {
    fuga(x2,y2);
    c3=col;
  }

  if (c4 == neutro) {
    fuga(x1,y2);
    c4=col;
  } 
  
  fuga(xm,y1);
  c5=col;
  fuga(x2,ym);
  c6=col;
  fuga(xm,y2);
  c7=col;
  fuga(x1,ym);
  c8=col;
  fuga(xm,ym);
  c9=col;
  
  if (x2-x1==2) {
    set(x1,y1,c1);
    set(xm,y1,c5);
    set(x2,y1,c2);
    set(x1,ym,c8);
    set(xm,ym,c9);
    set(x2,ym,c6);
    set(x1,y2,c4);
    set(xm,y2,c7);
    set(x2,y2,c3);
   } 
   else {
    if ((c1==c2) && (c1==c3) && (c1==c4) && (c1==c5) && 
        (c1==c6) && (c1==c7) && (c1==c8) && (c1==c9)) {
      rectMode(CORNERS);
      noStroke();
      fill(c1);
      rect(x1,y1,x2,y2);
    } 
    else {
      quadrante(x1,y1,xm,ym,c1,c5,c9,c8);
      quadrante(xm,y1,x2,ym,c5,c2,c6,c9);
      quadrante(x1,ym,xm,y2,c8,c9,c7,c4);
      quadrante(xm,ym,x2,y2,c9,c6,c3,c7);
    }
  }  
}


void fuga (int x, int y) {

  double xx,yy,a,b,ap,bp,dist;
  int i,c;
  
  xx=delta*x/256.0+xx1;
  yy=yy1-delta*y/256.0;
    
  ap=0.0;
  bp=0.0;
  i=0;
  dist=0.0;
  while ( (dist <= 4) && (i <= iter) ) {
    i++;
    a=(ap+bp)*(ap-bp)+xx;
    b=2.0*ap*bp+yy;
    dist=a*a+b*b;
    ap=a;
    bp=b;
  }
    
  if (i > iter) {
    col=color(0,0,0);
  }
  else {
      c=int((i-1)*255.0/(iter-1.0));
      col=color(255-c,255-c,c);
  }
}