Sas comares in politica
A una femina de cussas biddas de Cabuesusu, ddi ha' presentadu, una orta, custu dilemma, e goi dd'hada espostu una comare sua:
"Comare mia, su Sindigu senza cuncursu nč nudda, ha'leadu a tribagliare in sa Cumune sa fizza de Istevene Ischina. Su Segretariu l'hada preparadu tantas litteras e tantas bustas cun s'indirizziu e cun tottu e l'ha' dadu s'accumandu de las imbustare e che las ispedire. Su nadu su fattu. Solamente chi las had' imbustadas a casacciu e non li naro si chi es capitadu: sa littera a Mussennore est arrivada a sos Carabineris e cussa a su Prefetto l'ha'depida legger su Vicariu. Ah! Ma su Sindigu l'hada ammenettada: Un'attera or-ta sas litteras e i sas bustahana a esser medas de piusu, e si mancuna littera arrivad' a destinatariu ses licenziada. Medas, medas de piusu, in manera chi sia' pius discanzosu a fartare. Ma como deo mi domando e naro: tenimos unu Sindigu tontu o sa fizza de Istevene Ischina est'accozzada meda?"
"Pro rispondere Comare, a custu pensamentu sou, bisonza de fagher unu pagu de aritmetica. Si nois leamos tantas bustas, e las cambiamos de ordine si narada chi las permutamos."
Permutations[{a,b,c,d}]
{{a, b, c, d}, {a, b, d, c}, {a, c, b, d}, {a, c, d, b},
{a, d, b, c}, {a, d, c, b}, {b, a, c, d}, {b, a, d, c},
{b, c, a, d}, {b, c, d, a}, {b, d, a, c}, {b, d, c, a},
{c, a, b, d}, {c, a, d, b}, {c, b, a, d}, {c, b, d, a},
{c, d, a, b}, {c, d, b, a}, {d, a, b, c}, {d, a, c, b},
{d, b, a, c}, {d, b, c, a}, {d, c, a, b}, {d, c, b, a}}
"Comente si pode' biere, in calicunu assortimentu sa littera a addurada in su postu sou, su primu, in calicunu atteru cambia postu.E gai pro tottus sas litteras de s'alfabettu.B'ada assortimentos, sas permutaziones, inue tottus sas litteras cambian postu, pro esempiu {d,c,a,b}. Sas primas si naran permutaziones cun d'unu puntu fissu, sas segundas si naran disordinadas cumpletamente. Pro che ogare de tottus sas permutaziones solu sas chi sunu disordinadas si faghet goi:"
DiQ[p_?PermutationQ]:=
!(Apply[Or,Map[(#==p[[#]])&,Range[Length[p]]]])
NumeruDeDisordinadas[0]=1;
NumeruDeDisordinadas[n_]:=
n*NumeruDeDisordinadas[n-1]+(-1)^n;
Discordantes[n_Integer]:=Discordantes[Range[n]]
Discordantes[p_?PermutationQ]:=
Select[Permutations[p],DiQ]
"Pro ottenner cussas de battoro elementos si faghede";
Table[NumeruDeDisordinadas[i],{i,1,4}]
{0, 1, 2, 9}
"E si si contan in sa tabella precedente cantas sunu, si biede chi sunu 9";
"Sa probabilidade chi sa impiegada noa hada de no inzertare mancunu destinatariu este, comente ischimos, una frazione chi in su numeratore hada iscrittu su numeru de sos casos favorevoles,disordinadas, e in su denominatore su numeru de sos casos possibiles,permutations. Tando, sas probabilidades, de una a deghe bustas, chi nessunu arrizzada sa busta giusta sunu:";
Table[N[NumeruDeDisordinadas[i]/(i!)],{i,1,10}]
{0, 0.5, 0.333333, 0.375, 0.366667, 0.368056, 0.367857, 0.367882, 0.367879, 0.367879}
"Comente si podet notare, tales probabilidades tendene rapidamente a unu numeru particulare chi non dipendede de su numeru de sas bustas. Tale numeru este 1/E";
N[1/E,6]
0.367879
"Si aumentamus sas bustas a chimbanta non cambiad nudda";
Table[N[NumeruDeDisordinadas[i]/(i!)],{i,1,50}]
{0, 0.5, 0.333333, 0.375, 0.366667, 0.368056, 0.367857, 0.367882, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879,
0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879, 0.367879}
"Tant'este chi si podet usare s'approssimazione a su numeru interu pius vicinu de n!/E pro ottenner NumeruDeDisordinadas, chi prima nos a' dadu pelea pro iscriere su programma";
Table[NumeruDeDisordinadas[i],{i,1,10}]
{0, 1, 2, 9, 44, 265, 1854, 14833, 133496, 1334961}
Table[Round[n!/N[E]],{n,1,10}]
{0, 1, 2, 9, 44, 265, 1854, 14833, 133496, 1334961}
"E quindiche su Sindigu no es tontu, e s'impiegada noa non si toccada."